ANSYS影响面计算与绘制方法介绍

Please Share Us

点击此处查看 ✿水哥原创ANSYS视频教程清单 ✿

水哥专属答疑服务已开通,点此此处查看详情

 影响线与影响面是在土木结构分析里面必须掌握的两个概念,工程设计很多时候需要借助影响线或者影响面来确定荷载最不利加载位置,尤其是在桥梁结构设计中。本公众号以前发过一篇关于采用ANSYS进行影响线计算的文章,相比于影响面计算,影响线较为简单,主要是针对一维杆梁系模型,且结构后处理也较为简单,下列链接为以前的文章,有兴趣的同学可以看看。
【案例分享】ANSYS影响线计算及后处理相关技巧介绍
对于平面问题或者板弯曲、壳单元结构等结构分析问题,计算模型为二维,外部荷载移动范围为一个面,这时若考虑结构某点应力或者位移的值,则可以表达为一个位置的函数F(x,y),同样按照影响线的概念绘出其图像,就可以得到一个曲面,这个面就称之为相应查看内容的影响面。
利用ANSYS计算影响面时,需要在加载面上选用数量足够多的加载点,反复进行静力分析以便提供绘制影响面的数据,其基本操作过程如下:
1、创建几何模型和有限元模型;
2、确定移动荷载加载范围,利用*get命令写循环获取该范围内的节点编号;
3、进入求解模块,利用循环加载求解结构在移动范围内的结构响应;
4、进入后处理,定义查看位置处所要查看内容的影响面数组,用*get命令获取影响面数据内容;
5、改变图形模式,利用DNSOL命令修改数据库结果,将影响面数据以垂直加载面的方式进行绘制,如单位力在XOY面内加载,则可将结果绘制到UZ方向。
【案例演示】如下所示连续梁,板面受移动荷载作用,绘制边跨跨中、中跨跨中竖向位移影响面。

ANSYS影响面计算与绘制方法介绍

命令流如下,可做参考:

finish
/clear
/prep7
et,1,shell181
mp,ex,1,3.0e4
mp,prxy,1,0.2
mp,dens,1,2500e-12
sectype,1,shell
secdata,100
blc4,,,3000,1000
agen,4,all,,,3000
aglue,all
kwpave,2
wprota,,,90
blc4,,,2000,1000
wpcsys,-1
asel,s,,,2
agen,3,all,,,3000
allsel,all
aglue,all
!=================
esize,300
amesh,all
!==================
nsel,s,loc,x,0
nsel,a,loc,x,3000*4
d,all,ux,0,,,,uz,uy
nsel,s,loc,z,-2000
d,all,all,0
!==================
allsel,all
!获取最大节点数目       
nodemax=ndinqr(0,13)   
!==================
!获取加载面的最大节点数目
nsel,s,loc,z,0
nmax2=ndinqr(0,13)
*get,n0,node,,num,min
*dim,JZnode,,nmax2
JZnode(1)=n0
*do,i,2,nmax2
jZnode(i)=ndnext(JZnode(i-1))
*enddo
finish
!==================
!加载求解
/solu
allsel,all
outres,all,all
*do,i,1,nmax2
fdele,all,all
f,jznode(i),fz,-1
solve
*enddo
finish
!====================
/post1
!节点202的UZ影响面
!节点42的UZ影响面
!单元135的MX影响面
*dim,Uz1,,nmax2
*dim,UZ2,,nmax2
*dim,MXX,,nmax2
*do,i,1,nmax2
set,i
Uz1(i)=uz(202)
UZ2(i)=uz(42)
*get,MXX(i),elem,135,smisc,4
*enddo
/graphics
*do,i,1,nodemax
dnsol,i,u,z,0
*enddo
!绘制202 UZ影响面
*do,i,1,nmax2
dnsol,jznode(i),u,z,uz1(i)
*enddo
plnsol,u,z
!绘制42 UZ影响面
*do,i,1,nmax2
dnsol,jznode(i),u,z,uz2(i)
*enddo
plnsol,u,z
!绘制单元135 MX影响面
*do,i,1,nmax2
dnsol,jznode(i),u,z,mxx(i)
*enddo
plnsol,u,z
/device,vector,1
plnsol,u,z

ANSYS影响面计算与绘制方法介绍

202竖向位移影响面(mm)

ANSYS影响面计算与绘制方法介绍

42竖向位移影响面(mm)

ANSYS影响面计算与绘制方法介绍

单元135MX影响面(N.mm)
祝好
ANSYS结构院
2020.06.15

欢迎扫描如下二维码关注本站微信公众号:ANSYS结构院

有时间麻烦帮忙点击下公众号文末的广告哦, 权当码字的辛苦费,感谢大家!

Please Share Us
© 版权声明
THE END
喜欢就支持一下吧
点赞0赞赏 分享
评论 共2条
头像
欢迎您留下宝贵的见解!
提交
头像

昵称

取消
昵称表情代码

YOU MAY LIKE…