表面效应单元系列教程之Surf153

        所谓表面效应单元，也即是指专门为施加复杂荷载以及表面效应而生的单元。目前为止，就对土木方向而言，表面效应单元家族有三种单元，分别是surf153、surf154以及surf156。其中surf153主要用于2D结构，154主要用于3D实体或者壳单元，156则主要用于3D实体单元的边线。

        今天，水哥就简单谈谈Surf153的一些特性及使用方法。

        Surf153称之为2D结构表面效应单元，主要用于Plane系列单元的边线，注意，该单元不能用于杆梁单元的边线。

        单元几何如下所示：

        上图中，阿拉伯数字代表了荷载的方向，1号和3号荷载，当荷载值为正值时，荷载方向为单元坐标系的Y轴方向，不同之处在于1号是施加均布荷载，3号则是施加随坐标渐变的压力荷载。

          2号荷载，当荷载值为正时，表示荷载方向沿着单元坐标系的X轴方向；4号荷载则表示施加任意方向的荷载，其方向角度根据当前I、J节点在整体坐标系中的坐标值决定。

         153的实常数一般除了第6项偶尔这设置附加质量外，其他项一般设为默认值，创建单元方法同接触单元类似，通过surf命令生成单元。

          该单元的关键项比较重要的是第2项、第6项、第11和12项，第2项决定了1号荷载和2号荷载施加时采用的坐标系，第6项决定了1号荷载和3号荷载的法向压力选项，第11和12只针对4号荷载，决定其具体的方向，以及是否采用投影长度。

        下面分别以实例来说明Surf153的使用方法。如下所示的四种结构，试分别采用Surf153施加相应的荷载。

命令流如下：

finish

/clear

/prep7

et,1,plane42

et,2,surf153

keyopt,2,11,2

mp,ex,1,2e5

mp,prxy,1,0.3

blc4,,,400,100

aatt,1,,1

mshkey,1

esize,10

amesh,all

nsel,s,loc,x,0

d,all,all

nsel,s,loc,y,100

type,2

esurf

nsel,all

/solu

!竖向均布荷载20

esel,s,type,,2

sfe,all,1,pres,,20

esel,all

/psf,pres,norm,2

eplot

solve

!水平均布荷载20

sfedele,all,all,all

esel,s,type,,2

sfe,all,2,pres,,20

esel,all

/psf,pres,tanx,2

eplot

solve

!竖向渐变荷载10~30

sfedele,all,all,all

esel,s,type,,2

sfe,all,3,pres,,10,0.0375

esel,all

solve

!斜向均布荷载

sfedele,all,all,all

ref=35*acos(-1)/180

esel,s,type,,2

sfe,all,4,pres,,20,-cos(ref),-sin(ref)

esel,all

solve