ANSYS影响线计算及后处理相关技巧介绍

        影响线的求解在对工程特殊结构进行设计时是一项比较重要的工作，例如在地铁车站设计时考虑地铁移动荷载轨道梁的内力计算。根据影响线的定义，基于ANSYS提供的荷载步、时间历程概念，利用ANSYS可以很方便的求出结构影响线。本文以一四跨连续梁为例，简要说明了采用ANSYS计算影响线的步骤及一些后处理技巧，并利用SAP2000做了对比分析，校核了计算结果。

        采用ANSYS绘制影响线的步骤如下：

一、结合单元划分，沿结构跨度等分，在N个等分点施加单位荷载F=1;

二、建立N个荷载步，也即是N个工况，每个荷载步对应时间取单位荷载所在位置坐标。

        三、求解所有工况；

        四、在时间历程后处理器中将需求截面内力定义为变量，由此绘制各定义变量相对时间的变化情况，也即是内力影响线。

        案例基本情况如下：（单位为m）

ANSYS建模如下：

finish

/clear

/prep7

et,1,beam188

mp,ex,1,3.0e4

mp,dens,1,2600e-12

mp,prxy,1,0.3

h=1500

b=600

sectype,1,beam,rect

secdata,b,h

L=55200    !结构总长

ELmentsize=200 !单元尺寸

Elmentnum=L/ELmentsize !结构单元个数

*do,i,1,Elmentnum+1

n,i,Elmentsize*(i-1)

*if,i,gt,1,then

e,i-1,i

*endif

*enddo

N1=node(8400,0,0)

N2=node(21400,0,0)

N3=node(46600,0,0)

!约束条件,两边交接,中间连续

d,1,uy,,,,,ux,rotx,roty

d,Elmentnum+1,uy,,,,,ux,rotx,roty

d,N1,uy

d,N2,uy

d,N3,uy

allsel,all

d,all,uz

!======================

!影响线求解

/solu

antype,0

outres,all,all

*do,j,1,Elmentnum+1

!对应的位置坐标

time,j*0.2

*if,j,gt,1,then

fdele,all,all

*endif

f,j,fy,-1

solve

*enddo

在后处理中需要掌握的技巧如下：

一、对单元表循环提取数据的操作

二、数组数据与后处理变量之间的相互转换

三、影响线数据的输出

后处理如下：

/post1

!定义两个数组存储数据

*dim,jianli,,Elmentnum !剪力

*dim,wanju,,Elmentnum  !弯矩

!需要查看影响线截面的位置坐标

location=8400

!对应的单元数

nn=location/elmentsize

*do,i,1,Elmentnum

set,i

!剪力提取

*get,JL,elem,nn,smisc,6

jianli(i)=JL

!弯矩提取

*get,WJ,elem,nn,smisc,3

wanju(i)=wj

*enddo

!导入数据到变量中

/post26

vput,wanju,2

vput,jianli,3

!弯矩影响线

plvar,2

!剪力影响线

plvar,3

在坐标为8400，也即第二个支撑点处的弯矩影响线如下：

剪力影响线如下：

为校核计算结果，采用SAP2000进行了同样的计算，相应的影响线如下：

        从两者图形来看，两者会因为单元个数而存在局部较小差异，但两者走向趋势一样，说明采用如上思路利用ANSYS计算结构影响线可行。

        最后说一句：采用两种计算软件计算影响线各有优势，例如ANSYS可以很方便的提取数据进行后续操作，而SAP等设计类软件则是操作简单可行，并且可以方便的进行车辆荷载模式以及加载路径的定义，获取结构内力包络图。整体来讲，工程中，在对类似工程进行包络设计时，还是以实际设计软件使用较多，一则建模方便，二则内力包络计算不需手动操作即可进行。本文目的只是提供一种采用ANSYS计算影响线的思路。