ANSYS后处理中如何获取地震响应整个过程中的最大值及相应时刻

Please Share Us

点击此处查看 ✿水哥原创ANSYS视频教程清单 ✿

水哥专属答疑服务已开通,点此此处查看详情

最近有不少同学咨询水哥做完地震时程分析后,如何获取结构在整个地震时程分析过程中的最大值、最大值出现的时刻及相应位置,本篇文章就简单提供APDL编程思路供大家参考,命令流可根据需要套用。
思路如下:
1、在进行地震分析之前首先合并单元、节点编号,并重新编号,以便节点和单元编号连续;
2、获取节点或者单元数目;
3、定义数组,维度同节点和单元数目相同,用于存储每个节点或者单元在整个时间历程中的最大值;
4、进入时间历程后处理器,利用循环以及Nsol、Esol、Get命令获取每个节点或者相应单元结果的最大值,并存储在第三步所定义的数组中;
5、利用循环,获取全部节点中的最大值,记录此时的点位及时间点,即为结构在整体地震时程分析过程中的最大值及时间点、位置。
下面分别以节点位移和杆单元轴力为例演示整个过程,仅供大家学习参考。
一、获取结构在整体地震分析过程中Y方向位移响应的最大值、最大值出现的时刻以及相应的节点编号。
!===================

!获取节点Y方向最大位移

!获取节点数目

*Get,Ncount,Node,0,num,count    

!存储各个节点的最大值

*Dim,Nmax,Array,Ncount  

!存储最大值对应的时间   

*Dim,Tmax,Array,Ncount     

!获取每一个节点在时间历程范围内的最大值

*Do,I,1,Ncount

Nsol,8,I,U,Y          

Plvar,8

!获取最大值

*Get,U_Max,Vari,8,Extrem,Vmax 

!获取最大值对应的时间点     

*Get,T_Max,Vari,8,Extrem,Tmax  

!获取最小值    

*Get,U_Min,Vari,8,Extrem,Vmin 

!获取最小值对应的时间点     

*Get,T_Min,Vari,8,Extrem,Tmin 

!绝对值与最大值相比较     

U_Min=Abs(U_Min)

U_Max=Abs(U_Max)           

*If,U_Max,Le,U_Min,Then

U_Max=U_Min

T_Max=T_Min

*Endif

Nmax(I)=U_Max

Tmax(I)=T_Max

*Enddo

!在所有节点的最大值中找到整个模型的最大值

Absnmax=Nmax(1)

Abstmax=Tmax(1)

Sign=1

*Do,I,1,Ncount

*If,Absnmax,Le,Nmax(I),Then

Absnmax=Nmax(I)

Abstmax=Tmax(I)

Sign=I

*Endif

*Enddo

!整个模型的最大值

*Status,Absnmax

!对应的时间点   

*Status,Abstmax  

!对应的节点编号 

*Status,I
二、获取结构在整体地震分析过程中轴力响应的最大值、最大值出现的时刻以及相应的节点编号
!===================

!获取轴力最大值

!获取单元数量

*Get,Ecount,Elem,0,Count

!存储最大值

*Dim,Emax,Array,Ecount 

!存储最大值对应的时间      

*Dim,Tmax,Array,Ecount        

!获取每一个单元在时间历程范围内的最大值

*Do,I,1,Ecount

Esol,2,I,,Ls,1           

Plvar,2

!获取最大值

*Get,U_Max,Vari,2,Extrem,Vmax 

!获取最大值对应的时间点     

*Get,T_Max,Vari,2,Extrem,Tmax 

!获取最小值     

*Get,U_Min,Vari,2,Extrem,Vmin 

!获取最小值对应的时间点    

*Get,T_Min,Vari,2,Extrem,Tmin 

!绝对值与最大值相比较     

U_Min=Abs(U_Min)

U_Max=Abs(U_Max)                  

*If,U_Max,Le,U_Min,Then

U_Max=U_Min

T_Max=T_Min

*Endif

Emax(I)=U_Max

Tmax(I)=T_Max

*Enddo

*Status,Emax

!在所有单元的最大值中找到整个模型的最大值

Absemax=Emax(1)

Abstmax=Tmax(1)

Sign=1

*Do,I,1,Ecount

*If,Absemax,Le,Emax(I),Then

Absemax=Emax(I)

Abstmax=Tmax(I)

Sign=I

*Endif

*Enddo

*Status,Absemax   !极大值

*Status,Abstmax   !对应的时间点

*Status,Sign      !对应的单元编号
祝好
ANSYS结构院
2021.4.13

欢迎扫描如下二维码关注本站微信公众号:ANSYS结构院

有时间麻烦帮忙点击下公众号文末的广告哦, 权当码字的辛苦费,感谢大家!

Please Share Us
© 版权声明
THE END
喜欢就支持一下吧
点赞2赞赏 分享
评论 抢沙发
头像
欢迎您留下宝贵的见解!
提交
头像

昵称

取消
昵称表情代码

    暂无评论内容

YOU MAY LIKE…