How to Apply Torque or Moment Load to Solid Elements in ANSYS APDL

How to Apply Torque or Moment Load to Solid Elements in ANSYS APDL

点击此处查看 ✿水哥原创ANSYS视频教程清单 ✿

水哥专属答疑服务已开通,点此此处查看详情

During finite element analysis, you may encounter situations where you need to apply a bending or torque load to solid elements. However, in ANSYS APDL, solid elements do not have commands to directly apply bending or torque loads like beam elements do, because solid element nodes only have translational degrees of freedom.

To address this problem, this article presents two common solutions:

  • Torque is essentially a moment, which is the product of force and lever arm. Therefore, if you need to apply torque, you can convert it into force and lever arm and directly apply the force to the corresponding section.
  • As mentioned earlier, solid elements have no rotational degrees of freedom. Therefore, introducing nodes with rotational degrees of freedom and performing certain coupling operations can achieve input of torque or bending moment.

The first method essentially involves applying the appropriate force. Here, we focus on discussing the implementation of the second method in ANSYS APDL.

1.Cerig rigid zone method

The cerig command establishes a certain rigid zone and applies the load to the main node connected to this rigid zone. To introduce nodes with rotational degrees of freedom, we often use mass elements (e.g., mass21) and assign a very small mass to the mass element.

This method essentially establishes constraint equations, but it should be noted that the constraint equations are linear, so this method is only suitable for linear problems. For large deformation and other nonlinear problems, this method is not applicable.

2. MPC184 rigid beam method

You are probably familiar with rigid beams, and the main element introduced is the MPC184 element, which can be made into a rigid beam by setting the element real constant. In the specific usage process, a node is established in the center of the component, and multiple rigid beams are formed with other force-bearing nodes to form a rigid surface. Finally, the load is directly applied to the central node of the component, and the load is transmitted through the rigid beams.

This method has a wider range of applications than the cerig rigid zone method and can also be used for large deformation analysis.

Here’s a simple example to demonstrate the specific usage process of the two methods:

A rectangular block made of steel with a cross-sectional size of 10mmX10mmX30mm is fixed at one end and subjected to a torque of 1 N.m at the other end. We will use the above two methods to solve this model.

1、Cerig rigid zone method:

Here is the APDL code:

finish
/clear
/prep7
et,1,solid186
et,2,mass21
r,2,1e-6
mp,ex,1,2.0e5
mp,prxy,1,0.3
mp,dens,1,7850e-12
blc4,,,10,10,30
esize,2
vmesh,all
!=========
*get,nodemax,node,0,num,maxd
n,nodemax+1,5,5,35
type,2
real,2
e,nodemax+1
!===============
nsel,s,loc,z,30
nsel,a,,,nodemax+1
cerig,nodemax+1,all,all
!===================
f,nodemax+1,mz,1e3
nsel,s,loc,z,0
d,all,all,0
!==============
/solu
allsel,all
solve

2. MPC184 rigid beam method

Here is the APDL code:

finish
/clear
/prep7
et,1,solid186
et,2,mpc184
keyopt,2,1,1
mp,ex,1,2.0e5
mp,prxy,1,0.3
mp,dens,1,7850e-12
blc4,,,10,10,30
esize,2
vmesh,all
!================
*get,nodemax,node,0,num,maxd
n,nodemax+1,5,5,35
nsel,s,loc,z,30
*get,node1,node,0,num,max
*get,node2,node,0,num,min
num1=node1-node2
type,2
e,nodemax+1,node2
*do,i,1,num1
e,nodemax+1,node2+i
*enddo
!=======
/solu
allsel,all
f,nodemax+1,mz,1e3
nsel,s,loc,z,0
d,all,all,0
allsel,all
solve

The comparison between the two models is as follows:

图片[1]-How to Apply Torque or Moment Load to Solid Elements in ANSYS APDL-峰设教育

Rigid region model

图片[2]-How to Apply Torque or Moment Load to Solid Elements in ANSYS APDL-峰设教育

MPC184 rigid beam

图片[3]-How to Apply Torque or Moment Load to Solid Elements in ANSYS APDL-峰设教育

Rigid region displacement cloud map

图片[4]-How to Apply Torque or Moment Load to Solid Elements in ANSYS APDL-峰设教育

Rigid beam displacement cloud map

图片[5]-How to Apply Torque or Moment Load to Solid Elements in ANSYS APDL-峰设教育

Rigid region von Mises stress cloud map

图片[6]-How to Apply Torque or Moment Load to Solid Elements in ANSYS APDL-峰设教育

Rigid beam von Mises stress cloud map

As shown in the comparison chart, the results of both models are consistent.

Good Luck!

 

欢迎搜索关注本站微信公众号:ANSYS结构院

如果觉得本网站的文章和资源对您的研究具有一定的帮助,欢迎给网站捐助,您的支持是我坚持下去的动力!

© 版权声明
THE END
喜欢就支持一下吧
点赞0赞赏 分享
评论 抢沙发
头像
欢迎您留下宝贵的见解!
提交
头像

昵称

取消
昵称表情代码

    暂无评论内容